//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
#property copyright "www,forex-tsd.com"
#property link      "www,forex-tsd.com"

#property indicator_chart_window
#property indicator_buffers 4
#property indicator_color1 DeepSkyBlue
#property indicator_color2 PaleVioletRed
#property indicator_color3 DeepSkyBlue
#property indicator_color4 PaleVioletRed
#property indicator_width3 3
#property indicator_width4 3

//
//
//
//
//

extern string TimeFrame             = "current time frame";
extern int    CfbDepth              = 1;
extern int    CfbPrice              = PRICE_WEIGHTED;
extern int    CfbNormalizePeriod    = 50;
extern int    CfbSmooth             = 8;
extern double CfbResultSmooth       = 1.5;
extern double CfbResultSmoothPhase  = 0.0;
extern bool   CfbResultSmoothDouble = true;
extern int    Depth1                = 10;
extern int    Depth2                = 20;
extern bool   Interpolate           = true;

extern string _                     = "alerts settings";
extern bool   alertsOn              = true;
extern bool   alertsOnCurrent       = true;
extern bool   alertsMessage         = true;
extern bool   alertsSound           = false;
extern bool   alertsEmail           = false;

//
//
//
//
//

double UpLine[];
double DnLine[]; 
double UpArrow[];
double DnArrow[]; 
double smax[];
double smin[];
double cfb[];
double trend[];
int    Ignore;

//
//
//
//
//

string indicatorFileName;
int    timeFrame;
bool   returnBars;
bool   calculateCfb;

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//

int init()
{
   IndicatorBuffers(8);
      SetIndexBuffer(0,UpLine);  
      SetIndexBuffer(1,DnLine);  
      SetIndexBuffer(2,UpArrow); SetIndexStyle(2,DRAW_ARROW); SetIndexArrow(2,159);
      SetIndexBuffer(3,DnArrow); SetIndexStyle(3,DRAW_ARROW); SetIndexArrow(3,159);
      SetIndexBuffer(4,smax);
      SetIndexBuffer(5,smin);
      SetIndexBuffer(6,cfb);
      SetIndexBuffer(7,trend);
      
      int Depths[] = {24,32,48,64,96,128,192};
   
          CfbDepth = MathMax(MathMin(CfbDepth,7),1)+7;
            Ignore = Depths[CfbDepth-8]+3;
            
      //
      //
      //
      //
      //
      
      indicatorFileName = WindowExpertName();
      returnBars        = TimeFrame=="returnBars";   if (returnBars)     return(0);
      calculateCfb      = TimeFrame=="calculateCfb"; if (calculateCfb) return(0);
      timeFrame         = stringToTimeFrame(TimeFrame);
      
      //
      //
      //
      //
      //
   
      IndicatorShortName(timeFrameToString(timeFrame)+ " cfb channel stop");
 
   return(0);
}

//
//
//
//
//
 
int deinit() { return(0); }

//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
//
//

double work[][1];
#define _cfb 0

//
//
//
//
//

int start()
{
   int i,r,n,depth,limit,counted_bars  = IndicatorCounted();
   
   if(counted_bars<0) return(-1);
   if(counted_bars>0) counted_bars--;
       limit = MathMin(Bars - counted_bars,Bars-1);
       if (ArrayRange(work,0)!=Bars) ArrayResize(work,Bars);
       if (returnBars) { UpLine[0] = limit+1; return(0); }

   //
   //
   //
   //
   //

   if (calculateCfb || timeFrame==Period())
   {

   //
   //
   //
   //
   //

   for(i = limit,r=Bars-i-1; i >= 0 ; i--,r++)
   {
      double ratio = 0;
      double cfb   = iDSmooth(iCfb(Bars,iMA(NULL,0,1,0,MODE_SMA,CfbPrice,i),CfbDepth,CfbSmooth,r),CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,i);

      //
      //
      //
      //
      //
         
         work[r][_cfb] = cfb;
            double max = cfb;
            double min = cfb;
            if (r>=Ignore)
               for (int k=1; k<CfbNormalizePeriod && (r-k)>=0; k++)
                  {
                     min = MathMin(work[r-k][_cfb],min);
                     max = MathMax(work[r-k][_cfb],max);
                  }
            if (min!=max)
                  ratio = (cfb-min)/(max-min);
                  depth = MathRound( Depth1 + ratio*(Depth2-Depth1));
 
          //
          //
          //
          //
          //
          
          if (High[i] > smax[i+1])
                smax[i] =  High[i];
          else  smax[i] = (High[iHighest(NULL,0,MODE_HIGH,depth,i)]+smax[i+1])/2.0;
          
          if (Low[i] < smin[i+1])
                smin[i] =  Low[i];
          else  smin[i] = (Low[iLowest(NULL,0,MODE_LOW,depth,i)]+smin[i+1])/2.0; 
          
             UpLine[i]  = EMPTY_VALUE;
             DnLine[i]  = EMPTY_VALUE;
             UpArrow[i] = EMPTY_VALUE;
             DnArrow[i] = EMPTY_VALUE;
             trend[i]   = trend[i+1]; 
   
         //
         //
         //
         //
         //
         
	      if (Close[i]>smax[i+1]) trend[i]= 1; 
	      if (Close[i]<smin[i+1]) trend[i]=-1;
	      if (trend[i]>0 && smin[i]<smin[i+1]) smin[i]=smin[i+1];
	      if (trend[i]<0 && smax[i]>smax[i+1]) smax[i]=smax[i+1];
         if (trend[i] == 1)
            {  
               UpLine[i] = smin[i]; if (trend[i+1]!= 1) UpArrow[i] = UpLine[i];
            }
         if (trend[i] ==-1)
            {  
               DnLine[i] = smax[i]; if (trend[i+1]!=-1) DnArrow[i] = DnLine[i];
            }
      }
      manageAlerts();
      return(0);
   }
   
   
     limit = MathMax(limit,MathMin(Bars-1,iCustom(NULL,timeFrame,indicatorFileName,"returnBars",0,0)*timeFrame/Period()));
     
     for(i=limit; i>=0; i--)
     {
     int y     = iBarShift(NULL,timeFrame,Time[i]);
     UpLine[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,0,y);
     DnLine[i] = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,1,y);
     UpArrow[i]= EMPTY_VALUE;
     DnArrow[i]= EMPTY_VALUE;
     trend[i]  = iCustom(NULL,timeFrame,indicatorFileName,"calculateCfb",CfbDepth,CfbPrice,CfbNormalizePeriod,CfbSmooth,CfbResultSmooth,CfbResultSmoothPhase,CfbResultSmoothDouble,Depth1,Depth2,7,y);

     //
     //
     //
     //
     //

      if (UpLine[i]!= EMPTY_VALUE && UpLine[i+1]==EMPTY_VALUE) UpArrow[i]=UpLine[i];
      if (DnLine[i]!= EMPTY_VALUE && DnLine[i+1]==EMPTY_VALUE) DnArrow[i]=DnLine[i];
               
         //
         //
         //
         //
         //
                        
         if (!Interpolate || y==iBarShift(NULL,timeFrame,Time[i-1])) continue;

         //
         //
         //
         //
         //

         datetime time = iTime(NULL,timeFrame,y);
            for(n = 1; i+n < Bars && Time[i+n] >= time; n++) continue;
            for(k = 1; k < n; k++)
            {
               if (UpLine[i]!=EMPTY_VALUE && UpLine[i+n]!=EMPTY_VALUE) UpLine[i+k] = UpLine[i] + (UpLine[i+n]-UpLine[i])*k/n;
               if (DnLine[i]!=EMPTY_VALUE && DnLine[i+n]!=EMPTY_VALUE) DnLine[i+k] = DnLine[i] + (DnLine[i+n]-DnLine[i])*k/n;
            }
   }
   manageAlerts();  
   return(0);         
}

//
//
//
//
//

string sTfTable[] = {"M1","M5","M15","M30","H1","H4","D1","W1","MN"};
int    iTfTable[] = {1,5,15,30,60,240,1440,10080,43200};

//
//
//
//
//

int stringToTimeFrame(string tfs)
{
   tfs = StringUpperCase(tfs);
   for (int i=ArraySize(iTfTable)-1; i>=0; i--)
         if (tfs==sTfTable[i] || tfs==""+iTfTable[i]) return(MathMax(iTfTable[i],Period()));
                                                      return(Period());
}
string timeFrameToString(int tf)
{
   for (int i=ArraySize(iTfTable)-1; i>=0; i--) 
         if (tf==iTfTable[i]) return(sTfTable[i]);
                              return("");
}

//
//
//
//
//

string StringUpperCase(string str)
{
   string   s = str;

   for (int length=StringLen(str)-1; length>=0; length--)
   {
      int char = StringGetChar(s, length);
         if((char > 96 && char < 123) || (char > 223 && char < 256))
                     s = StringSetChar(s, length, char - 32);
         else if(char > -33 && char < 0)
                     s = StringSetChar(s, length, char + 224);
   }
   return(s);
}   
 
//
//
//
//
//

int    Depths[] = {2,3,4,6,8,12,16,24,32,48,64,96,128,192};
double workCfb[][28];

//
//
//
//
//

double iCfb(int totalBars, double price, int depth, int smooth, int i)
{
   if (ArrayRange(workCfb,0) != totalBars) ArrayResize(workCfb,totalBars);
         
   //
   //
   //
   //
   //

   double suma     = 0;
   double sumb     = 0;
   double cfb      = 0;
   double evenCoef = 1;
   double oddCoef  = 1;
   double avg      = 0;
         
      if (i>=smooth)
         for (int k=depth-1; k>=0; k--)
         {
            workCfb[i][k]    = iCfbFunc(totalBars,price,i,Depths[k],k);
            workCfb[i][k+14] = workCfb[i-1][k+14] + (workCfb[i][k]-workCfb[i-smooth][k])/smooth;

                  if ((k%2)==0)
                        { avg = oddCoef  * workCfb[i][k+14]; oddCoef  = oddCoef  * (1 - avg); }
                  else  { avg = evenCoef * workCfb[i][k+14]; evenCoef = evenCoef * (1 - avg); }
               
               suma += avg*avg*Depths[k];
               sumb += avg;
         }
      else for (k=depth-1; k>=0; k--) { workCfb[i][k] = 0; workCfb[i][k+14] = 0; }            

   //
   //
   //
   //
   //

   if (sumb != 0) cfb = suma/sumb;
   return(cfb);
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double  workCfbFunc[][70];
#define _prices 0
#define _roc    1
#define _value1 2
#define _value2 3
#define _value3 4

//
//
//
//

double iCfbFunc(int totalBars, double price, int r, int depth, int k)
{
   k *= 5;
      if (ArrayRange(workCfbFunc,0) != totalBars) ArrayResize(workCfbFunc,totalBars);
      if (r<=(depth+1))
      {
         workCfbFunc[r][k+_prices] = 0;
         workCfbFunc[r][k+_roc]    = 0;
         workCfbFunc[r][k+_value1] = 0;
         workCfbFunc[r][k+_value2] = 0;
         workCfbFunc[r][k+_value3] = 0;
         return(0);
      }         
      workCfbFunc[r][k+_prices] = price; 

   //
   //
   //
   //
   //

      workCfbFunc[r][k+_roc]    = MathAbs(workCfbFunc[r][k+_prices] - workCfbFunc[r-1][k+_prices]);
      workCfbFunc[r][k+_value1] = workCfbFunc[r-1][k+_value1] - workCfbFunc[r-depth][k+_roc] + workCfbFunc[r][k+_roc];
      workCfbFunc[r][k+_value2] = workCfbFunc[r-1][k+_value2] - workCfbFunc[r-1][k+_value1] + workCfbFunc[r][k+_roc]*depth;
      workCfbFunc[r][k+_value3] = workCfbFunc[r-1][k+_value3] - workCfbFunc[r-1-depth][k+_prices] + workCfbFunc[r-1][k+_prices];
   
      double dividend = MathAbs(depth*workCfbFunc[r][k+_prices]-workCfbFunc[r][k+_value3]);

      //
      //
      //
      //
      //
         
   if (workCfbFunc[r][k+_value2] != 0)
         return( dividend / workCfbFunc[r][k+_value2]);
   else  return(0.00);            
}

//+------------------------------------------------------------------
//|                                                                  
//+------------------------------------------------------------------
//
//
//
//
//

double wrk[][20];

#define bsmax  5
#define bsmin  6
#define volty  7
#define vsum   8
#define avolty 9

//
//
//
//
//

double iDSmooth(double price, double length, double phase, bool isDouble, int i, int s=0)
{
   if (isDouble)
         return (iSmooth(iSmooth(price,MathSqrt(length),phase,i,s),MathSqrt(length),phase,i,s+10));
   else  return (iSmooth(price,length,phase,i,s));
}

//
//
//
//
//

double iSmooth(double price, double length, double phase, int i, int s=0)
{
   if (length <=1) return(price);
   if (ArrayRange(wrk,0) != Bars) ArrayResize(wrk,Bars);
   
   int r = Bars-i-1; 
      if (r==0) { for(int k=0; k<7; k++) wrk[r][k+s]=price; for(; k<10; k++) wrk[r][k+s]=0; return(price); }

   //
   //
   //
   //
   //
   
      double len1   = MathMax(MathLog(MathSqrt(0.5*(length-1)))/MathLog(2.0)+2.0,0);
      double pow1   = MathMax(len1-2.0,0.5);
      double del1   = price - wrk[r-1][bsmax+s];
      double del2   = price - wrk[r-1][bsmin+s];
      double div    = 1.0/(10.0+10.0*(MathMin(MathMax(length-10,0),100))/100);
      int    forBar = MathMin(r,10);
	
         wrk[r][volty+s] = 0;
               if(MathAbs(del1) > MathAbs(del2)) wrk[r][volty+s] = MathAbs(del1); 
               if(MathAbs(del1) < MathAbs(del2)) wrk[r][volty+s] = MathAbs(del2); 
         wrk[r][vsum+s] =	wrk[r-1][vsum+s] + (wrk[r][volty+s]-wrk[r-forBar][volty+s])*div;
         
         //
         //
         //
         //
         //
   
         wrk[r][avolty+s] = wrk[r-1][avolty+s]+(2.0/(MathMax(4.0*length,30)+1.0))*(wrk[r][vsum+s]-wrk[r-1][avolty+s]);
            if (wrk[r][avolty+s] > 0)
               double dVolty = wrk[r][volty+s]/wrk[r][avolty+s]; else dVolty = 0;   
	               if (dVolty > MathPow(len1,1.0/pow1)) dVolty = MathPow(len1,1.0/pow1);
                  if (dVolty < 1)                      dVolty = 1.0;

      //
      //
      //
      //
      //
	        
   	double pow2 = MathPow(dVolty, pow1);
      double len2 = MathSqrt(0.5*(length-1))*len1;
      double Kv   = MathPow(len2/(len2+1), MathSqrt(pow2));

         if (del1 > 0) wrk[r][bsmax+s] = price; else wrk[r][bsmax+s] = price - Kv*del1;
         if (del2 < 0) wrk[r][bsmin+s] = price; else wrk[r][bsmin+s] = price - Kv*del2;
	
   //
   //
   //
   //
   //
      
      double R     = MathMax(MathMin(phase,100),-100)/100.0 + 1.5;
      double beta  = 0.45*(length-1)/(0.45*(length-1)+2);
      double alpha = MathPow(beta,pow2);

         wrk[r][0+s] = price + alpha*(wrk[r-1][0+s]-price);
         wrk[r][1+s] = (price - wrk[r][0+s])*(1-beta) + beta*wrk[r-1][1+s];
         wrk[r][2+s] = (wrk[r][0+s] + R*wrk[r][1+s]);
         wrk[r][3+s] = (wrk[r][2+s] - wrk[r-1][4+s])*MathPow((1-alpha),2) + MathPow(alpha,2)*wrk[r-1][3+s];
         wrk[r][4+s] = (wrk[r-1][4+s] + wrk[r][3+s]); 

   //
   //
   //
   //
   //

   return(wrk[r][4+s]);
}

//
//
//
//
//

void manageAlerts()
{
   if (! calculateCfb && alertsOn)
   {
      if (alertsOnCurrent)
           int whichBar = 0;
      else     whichBar = 1; whichBar = iBarShift(NULL,0,iTime(NULL,timeFrame,whichBar));
      if (trend[whichBar] != trend[whichBar+1])
      {
         if (trend[whichBar] == 1) doAlert(whichBar,"buy");
         if (trend[whichBar] ==-1) doAlert(whichBar,"sell");
      }         
   }
}   

//
//
//
//
//

void doAlert(int forBar, string doWhat)
{
   static string   previousAlert="nothing";
   static datetime previousTime;
   string message;
   
   if (previousAlert != doWhat || previousTime != Time[forBar]) {
       previousAlert  = doWhat;
       previousTime   = Time[forBar];

       //
       //
       //
       //
       //

       message =  StringConcatenate(Symbol()," at ",TimeToStr(TimeLocal(),TIME_SECONDS)," - ",timeFrameToString(timeFrame)+" cfb channel stop ",doWhat);
          if (alertsMessage) Alert(message);
          if (alertsEmail)   SendMail(StringConcatenate(Symbol()," cfb channel stop "),message);
          if (alertsSound)   PlaySound("alert2.wav");
   }
}

//
//
//
//
//