@echo off
if "%1" == "" goto :BEGIN
if "%1" == "LINK" goto :LINK
goto ERROR

:BEGIN
rem Проверить наличие каталога MQL5 в каталоге запускаемого файла
for /f %%i in (%0) do set MQL5DIR=%%~dpiMQL5
if exist "%MQL5DIR%" goto :OK1
echo Каталог %MQL5DIR% не существует! Как на него создать ссылки?!
goto :END
:OK1

rem Для всех каталогов терминала обновить ссылки
set TERMINALDIR=%APPDATA%\MetaQuotes\Terminal
for /f "delims=" %%i in ('dir "%TERMINALDIR%" /b') do call %0 LINK "%TERMINALDIR%\%%~nxi\MQL5" "%MQL5DIR%"
pause
goto :END

:LINK
rem Сделать ссылки %2 на %3

rem Если подкаталога MQL5 не существует, то пропускаем такой каталог
if not exist %2 goto :END

rem Убрать обрамляющие кавычки "123..890\MQL5" => 123..890\MQL5
for /f %%i in (%2) do set DIR=%%~i

rem Получить текущую дату
for /F %%i in ('date /t') do set DATE=%%i

rem Проверить наличие целевой папки
if not exist "%DIR%.%DATE%" goto :OK2
echo Каталог "%DIR%.%DATE%" уже существует! Пропуск...
goto :END

:OK2
rem Переименовать каталог 123..890\MQL5 => 123..890\MQL5.ДАТА
move "%DIR%" "%DIR%.%DATE%" > NUL

rem Создать ссылку
mklink /j %2 %3

goto :END

:ERROR
echo.
echo Something wrong!
echo.

:END