// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © wppqqppq

//@version=5
indicator('Prop Firm Passed 5m Scalping', 'PFP', overlay = true, max_labels_count = 500, max_lines_count = 500)

intraTf = timeframe.isintraday

////// Inputs //////
gpBs = ''
maxLv = input.int(5, 'Max Levels to Show', tooltip = 'Max number of lines to show on each side.', minval = 1, maxval = 100, group = gpBs)
lookback = input.int(300, 'Lookback Bars', minval = 1, maxval = 5000, group = gpBs)
bullLvCor = input.color(color.aqua, 'Level Color　Bullish', group = gpBs, inline = 'l')
bearLvCor = input.color(color.rgb(233, 30, 99), 'Bearish', group = gpBs, inline = 'l')
lvStyle = input.string('Solid', 'Line Style', options = ['Solid', 'Dotted', 'Dashed'], group = gpBs, inline = '1')
lvWid = input.int(1, 'Width', group = gpBs, inline = '1')
showLeg = input.bool(true, 'Show Leg Number', group = gpBs)

gpBias = 'Curret Bias'
showBias = input.bool(true, 'Show Current Bias', group = gpBias)
biasTbPos = input.string("Top Right", "Location", 
             ["Top Right" , "Middle Right"  , "Bottom Right" , 
              "Top Center", "Middle Center" , "Bottom Center", 
              "Top Left"  , "Middle Left"   , "Bottom Left" ], group = gpBias, inline = "b")
biasTbSize = input.string("Auto", "Size", 
             ["Auto",  "Huge",  "Large", "Normal", "Small", "Tiny"], group = gpBias, inline = "b")
biasBullCor = input.color(color.new(color.aqua, 80), 'Background Color　Bullish', group = gpBias, inline = "c")
biasBearCor = input.color(color.new(color.rgb(233, 30, 99), 80), 'Bearish', group = gpBias, inline = "c")

gpSetup = 'Setup'
showEt = input.bool(true, 'Show Entry Level', group = gpSetup)
etCor = input.color(color.orange, 'Color', group = gpSetup, inline = '1')
etStyle = input.string('Dashed', 'Style', options = ['Solid', 'Dotted', 'Dashed'], group = gpSetup, inline = '1')
etWid = input.int(1, 'Width', group = gpSetup, inline = '1')
showEtBar = input.bool(true, 'Show Entry Bar', group = gpSetup)

gpFix = 'Fixing'
fxLookback = input.int(2, 'Lookback Days', group = gpFix, minval = 1, maxval = 10)
highlightCurFx = input.bool(true, 'Highlight Most Recent', group = gpFix, inline = '0') and fxLookback > 1
showFxLb = input.bool(true, 'Show Label', group = gpFix, inline = '0') and intraTf
showTkFx = input(true, 'Tokyo Fix', group = gpFix, inline = '1') and intraTf
tkFxCor = input.color(color.blue, 'Color', group = gpFix, inline = '1')
tkFxStyle = input.string('Dotted', 'Style', options = ['Solid', 'Dotted', 'Dashed'], group = gpFix, inline = '1')
tkFxWid = input.int(1, 'Width', group = gpFix, inline = '1')
showLdnFx = input(true, 'London Fix', group = gpFix, inline = '2') and intraTf
ldnFxCor = input.color(color.rgb(26, 128, 0), 'Color', group = gpFix, inline = '2')
ldnFxStyle = input.string('Dotted', 'Style', options = ['Solid', 'Dotted', 'Dashed'], group = gpFix, inline = '2')
ldnFxWid = input.int(1, 'Width', group = gpFix, inline = '2')

gpTm = 'Time Windows'
noWeekendSessions = ':23456'
onlyInSession = input.bool(false, 'Filter with Market Sessions', group = gpTm) and intraTf
useGmt = input.string('GMT+8', 'Timezone', group = gpTm, options = ['GMT-12','GMT-11','GMT-10','GMT-9','GMT-8','GMT-7','GMT-6','GMT-5','GMT-4','GMT-3','GMT-2','GMT-1','GMT+0','GMT+1','GMT+2','GMT+3','GMT+4','GMT+5','GMT+5:30','GMT+5:45','GMT+6','GMT+6:30','GMT+7','GMT+8','GMT+9','GMT+10','GMT+11','GMT+12','GMT+13','GMT+14'])
useAsSess = input.bool(true, 'Asian Session', group = gpTm, inline = 'a')
userAsSess = input.session('0700-1600', 'Time', group = gpTm, inline = 'a') + noWeekendSessions
showAsBg = input.bool(true, 'Show Asian Session Background', group = gpTm, inline = 'a2')
asBgCor = input.color(color.new(color.red, 90), 'Color', group = gpTm, inline = 'a2')
useLdnSess = input.bool(true, 'London Session', group = gpTm, inline = 'l')
userLdnSess = input.session('1500-0000', 'Time', group = gpTm, inline = 'l') + noWeekendSessions
showLdnBg = input.bool(true, 'Show London Session Background', group = gpTm, inline = 'l2')
ldnBgCor = input.color(color.new(color.yellow, 90), 'Color', group = gpTm, inline = 'l2')
useNySess = input.bool(true, 'New York Session', group = gpTm, inline = 'n')
userNySess = input.session('2000-0500', 'Time', group = gpTm, inline = 'n') + noWeekendSessions
showNyBg = input.bool(true, 'Show New York Session Background', group = gpTm, inline = 'n2')
nyBgCor = input.color(color.new(color.aqua, 90), 'Color', group = gpTm, inline = 'n2')

gpAlt = 'Alert'
altLv = input.bool(true, 'Alert on Level Formed', group = gpAlt)
altReb = input.bool(true, 'Alert on Rebalanced', group = gpAlt)
altEt = input.bool(true, 'Alert on Entry Occured', group = gpAlt)

////// Types //////
type leg
    int _dir
    float _price
    int _num

////// Constants //////
var NONE_COLOR = color.new(color.white, 100)
var BULL_DIR = 1
var BEAR_DIR = -1
var NONE_DIR = 0
var LINE_OFFSET = 10
var MAX_LINE = 100 // 100 on each side = 200 lines in total
var MAX_BEAR_CD_LOOKBACK = 2
var GMT = 'GMT+0'
var GMT_DST = 'GMT+1'
var AS_SESS = '2300-0900'
var LDN_SESS = '0700-1600'
var NY_SESS = '1300-2200'
var TOKYO_FIX = '0055-0100' // 9:55am Tokyo time(GMT+9)
var LONDON_FIX = '1600-1601' // 4pm London time(if DST: GMT+1, else: GMT+0)
var LEG_ORIGIN_TXT = '★'

var DEBUG = false

////// Variables //////
labelOffset = time_close + 7 * timeframe.multiplier * 60 * 1000

////// Functions //////
IsTimeInRange(sess, tz) => not na(time("1", sess, tz))

LineStyle(str) =>
    switch str
        "Solid" => line.style_solid
        "Dotted" => line.style_dotted
        "Dashed" => line.style_dashed

CandleDir(i=0) =>
    close[i] > open[i] ? BULL_DIR : (close[i] < open[i] ? BEAR_DIR : NONE_DIR)

IsBullDir(dir) =>
    dir == BULL_DIR

IsBearDir(dir) =>
    dir == BEAR_DIR

IsNeutralDir(dir) =>
    dir == NONE_DIR
    
IsBullCandle(i=0) =>
    IsBullDir(CandleDir(i))

IsBearCandle(i=0) =>
    IsBearDir(CandleDir(i))

IsNeutralCandle(i=0) =>
    IsNeutralDir(CandleDir(i))

IsLineExpired(line ln) =>
    bar_index - line.get_x1(ln) > lookback

IsDst()=>
    int previousSunday = dayofmonth - dayofweek + 1
    bool nyDST = na
    bool ukDST = na
    bool sydDST = na
    
    if month < 3 or month > 11
        nyDST := false
        ukDST := false
        sydDST := true
    else if month > 4 and month < 10
        nyDST := true
        ukDST := true
        sydDST := false
    else if month == 3
        nyDST := previousSunday >= 8
        ukDST := previousSunday >= 24
        sydDST := true
    else if month == 4
        nyDST := true
        ukDST := true
        sydDST := previousSunday <= 0
    else if month == 10
        nyDST := true
        ukDST := previousSunday <= 24
        sydDST := previousSunday >= 0
    else // month == 11
        nyDST := previousSunday <= 0
        ukDST := false
        sydDST := true
    [nyDST, ukDST, sydDST]

TrimLineArr(array<line> arr, max) =>
    if arr.size() > max
        ln = arr.shift()
        line.delete(ln)

TrimLabelArr(array<label> arr, max) =>
    if arr.size() > max
        ln = arr.shift()
        label.delete(ln)

Icon(x) =>
    txt = ''
    if IsBullDir(x)
        txt := '????'
    else if IsBearDir(x)
        txt := '????'
    txt

TableLoc(x) => 
    y   = str.split(str.lower(x), " ")
    out = ""
    for i = 0 to array.size(y) - 1
        out := out + array.get(y, i)
        if i != array.size(y) - 1
            out := out + "_"
    out
TableCellTxt(x) =>
    Icon(x)

TableTxtCor(x) =>
    txtCor = #DCDCDC
    if IsBullDir(x)
        txtCor := bullLvCor
    else if IsBearDir(x)
        txtCor := bearLvCor
    txtCor

TableCellCor(x) =>
    cellCor = #1C1C1C
    if IsBullDir(x)
        cellCor := biasBullCor
    else if IsBearDir(x)
        cellCor := biasBearCor
    cellCor

////// Time //////
[nyDST, ukDST, sydDST] = IsDst()
inAs = onlyInSession and useAsSess and IsTimeInRange(userAsSess, useGmt)
inLdn = onlyInSession and useLdnSess and IsTimeInRange(userLdnSess, useGmt)
inNy = onlyInSession and useNySess and IsTimeInRange(userNySess, useGmt)
inSess = onlyInSession ? (inAs or inLdn or inNy) : true

bgcolor(inAs and showAsBg? asBgCor : NONE_COLOR)
bgcolor(inLdn and showLdnBg? ldnBgCor : NONE_COLOR)
bgcolor(inNy and showNyBg? nyBgCor : NONE_COLOR)

////// Main Logic //////
var int bias = na

// Bearish Levels : bull + bear + bear, ignore neutral candles in between
var prevCandleArr = array.new_int()
var bearLvArr = array.new_line()
var float mostRecentBear = na

if not IsNeutralCandle(1)
    prevCandleArr.push(CandleDir(1))
    if prevCandleArr.size() > MAX_BEAR_CD_LOOKBACK
        prevCandleArr.shift()

isBearLv = false
if prevCandleArr.size() == MAX_BEAR_CD_LOOKBACK
    isBearLv := IsBullDir(prevCandleArr.get(0)) and IsBearDir(prevCandleArr.get(1)) and IsBearCandle()

if isBearLv
    bias := BEAR_DIR

if inSess and isBearLv
    mostRecentBear := close[1]
    bearLvArr.push(line.new(bar_index - 1, mostRecentBear, bar_index + LINE_OFFSET, mostRecentBear, style = LineStyle(lvStyle), width = lvWid, color = bearLvCor))
    TrimLineArr(bearLvArr, MAX_LINE)

invalidLvIndexArr = array.new_int()
for [i, ln] in bearLvArr
    if close > line.get_y1(ln) or IsLineExpired(ln)
        invalidLvIndexArr.push(i)
while invalidLvIndexArr.size() > 0
    i = invalidLvIndexArr.pop()
    ln = bearLvArr.remove(i)
    line.delete(ln)

for [i, ln] in bearLvArr
    line.set_x2(ln, bar_index + LINE_OFFSET)
    line.set_color(ln, bearLvArr.size() - i > maxLv ? NONE_COLOR : bearLvCor)

// Bullish Levels : bull & close > last bear open
var float mostRecentBull = na
var bullLvArr = array.new_line()
var lastBearCdOpen = open
var lastBearCdIndex = bar_index
var isLastBearCdBroken = false

if IsBearCandle()
    lastBearCdOpen := open
    lastBearCdIndex := bar_index
    isLastBearCdBroken := false
isBullLv = IsBullCandle() and close > lastBearCdOpen and not isLastBearCdBroken
if isBullLv
    isLastBearCdBroken := true
    bias := BULL_DIR

if inSess and isBullLv
    mostRecentBull := lastBearCdOpen
    bullLvArr.push(line.new(lastBearCdIndex, mostRecentBull, bar_index + LINE_OFFSET, mostRecentBull, style = LineStyle(lvStyle), width = lvWid, color = bullLvCor))
    TrimLineArr(bullLvArr, MAX_LINE)

invalidLvIndexArr := array.new_int()
for [i, ln] in bullLvArr
    if close < line.get_y1(ln) or IsLineExpired(ln)
        invalidLvIndexArr.push(i)
while invalidLvIndexArr.size() > 0
    i = invalidLvIndexArr.pop()
    ln = bullLvArr.remove(i)
    line.delete(ln)

for [i, ln] in bullLvArr
    line.set_x2(ln, bar_index + LINE_OFFSET)
    line.set_color(ln, bullLvArr.size() - i > maxLv ? NONE_COLOR : bullLvCor)

biasChanged = ta.change(bias)

// Alerts
if inSess and altLv and (isBullLv or isBearLv)
    txt = Icon(bias) + ' Level Formed'
    alert(txt, alert.freq_once_per_bar_close)

////// Leg Number //////
var legLbArr = array.new_label()
if showLeg and barstate.islast
    while legLbArr.size() > 0
        lb = legLbArr.pop()
        label.delete(lb)
    legLbArr := array.new_label()
    legArr = array.new<leg>(bullLvArr.size() + bearLvArr.size(), na)
    bullIndex = 0
    bearIndex = 0
    for i = 0 to legArr.size() - 1
        if bullIndex < bullLvArr.size() and bearIndex < bearLvArr.size()
            bullLv = bullLvArr.get(bullIndex)
            bearLv = bearLvArr.get(bearIndex)
            if bullLv.get_x1() < bearLv.get_x1()
                legArr.set(i, leg.new(BULL_DIR, bullLv.get_y1(), 0))
                bullIndex := bullIndex + 1
            else
                legArr.set(i, leg.new(BEAR_DIR, bearLv.get_y1(), 0))
                bearIndex := bearIndex + 1
        else if bullIndex < bullLvArr.size()
            legArr.set(i, leg.new(BULL_DIR, line.get_y1(bullLvArr.get(bullIndex)), 0))
            bullIndex := bullIndex + 1
        else if bearIndex < bearLvArr.size()
            legArr.set(i, leg.new(BEAR_DIR, line.get_y1(bearLvArr.get(bearIndex)), 0))
            bearIndex := bearIndex + 1
        else
            break

    bullLegNum = 0
    bearLegNum = 0
    for [_, l] in legArr
        cor = NONE_COLOR
        if na(l)
            break
        else if IsBullDir(l._dir)
            l._num := bullLegNum
            bullLegNum := bullLegNum + 1
            bearLegNum := 0
            cor := bullLvCor
        else
            l._num := bearLegNum
            bearLegNum := bearLegNum + 1
            bullLegNum := 0
            cor := bearLvCor
        legLbArr.push(label.new(labelOffset, l._price, l._num == 0 ? LEG_ORIGIN_TXT : str.tostring(l._num), xloc = xloc.bar_time, color = NONE_COLOR, style = label.style_label_left, textcolor = cor, textalign = text.align_left))

    if bullLvArr.size() > maxLv
        find = 0
        for [i, l] in legArr
            if find == bullLvArr.size() - maxLv
                break
            if IsBullDir(l._dir)
                label.set_textcolor(legLbArr.get(i), NONE_COLOR)
                find := find + 1
    if bearLvArr.size() > maxLv
        find = 0
        for [i, l] in legArr
            if find == bearLvArr.size() - maxLv
                break
            if IsBearDir(l._dir)
                label.set_textcolor(legLbArr.get(i), NONE_COLOR)
                find := find + 1

////// Rebalancing //////
var isTested = false
if biasChanged or (inSess and (isBullLv or isBearLv))
    isTested := false

if inSess and barstate.isconfirmed
    if not na(mostRecentBull)
        isTested := isTested or (IsBullDir(bias) and IsBearDir(CandleDir()) and close > mostRecentBull)
    if not na(mostRecentBear)
        isTested := isTested or (IsBearDir(bias) and IsBullDir(CandleDir()) and close < mostRecentBear)
plotshape(DEBUG and isTested, style = shape.xcross, color = color.aqua, location = location.bottom, size = size.small)

isOnTested = isTested and not isTested[1]
plotshape(DEBUG and isOnTested, style = shape.diamond, color = color.yellow, location = location.bottom, size = size.small)

////// Entry Level //////
var line entryLine = na
if inSess and showEt
    if biasChanged or isOnTested
        if not na(entryLine)
            line.delete(entryLine)
    if isOnTested
        entryLine := line.new(bar_index, close[1], bar_index + 1, close[1], extend = extend.right, color = etCor, style = LineStyle(etStyle), width = etWid)

// Alerts
if altReb and isOnTested
    txt = Icon(bias) + ' Level Rebalanced
Entry Price: ' + str.tostring(close[1], format.mintick)
    alert(txt, alert.freq_once_per_bar_close)

////// Entry Bar //////
var entered = false
if inSess and showEtBar
    if biasChanged
        entered := false
    entryPrice = line.get_y1(entryLine)
    if bar_index > line.get_x1(entryLine) and (IsBearDir(bias) ? low < entryPrice : high > entryPrice)
        entered := true

plotshape(DEBUG and entered, style = shape.xcross, color = color.aqua, location = location.top, size = size.small)

isOnEntered = entered and not entered[1]

longEntry = isOnEntered and IsBullDir(bias)
shortEntry = isOnEntered and IsBearDir(bias)

plotshape(longEntry, style = shape.triangleup, location = location.belowbar, color = bullLvCor)
plotshape(shortEntry, style = shape.triangledown, location = location.abovebar, color = bearLvCor)

// Alerts
if inSess and altEt and (longEntry or shortEntry)
    txt = 'Enter ' + (longEntry ? 'Long' : 'Short') + ' ' + Icon(bias)
    alert(txt, alert.freq_once_per_bar)

////// Bias Table //////
var slTb = table.new(TableLoc(biasTbPos), 1, 1, #1C1C1C, #1C1C1C, 1, #1C1C1C, 2)

table.clear(slTb, 0, 0, 0, 0)

if inSess and barstate.islast and showBias
    table.cell(slTb, 0, 0, TableCellTxt(bias), text_color = TableTxtCor(bias), bgcolor = TableCellCor(bias), text_size = TableLoc(biasTbSize))

////// Fixing //////
// Tokyo
var tkFxLnArr = array.new_line()
var tkFxLbArr = array.new_label()
inTkFx = IsTimeInRange(TOKYO_FIX, GMT)
isTkFxBar = inTkFx and not inTkFx[1]

if showTkFx and isTkFxBar
    wid = highlightCurFx ? tkFxWid + 1 : tkFxWid
    tkFxLnArr.push(line.new(bar_index, open, bar_index + LINE_OFFSET, open, color = tkFxCor, style = LineStyle(tkFxStyle), width = wid))
    TrimLineArr(tkFxLnArr, fxLookback)
    if showFxLb
        tkFxLbArr.push(label.new(x=labelOffset, y=open, text='Tokyo Fix', xloc=xloc.bar_time, color = NONE_COLOR, style=label.style_label_left, textcolor=tkFxCor, textalign=text.align_left))
        TrimLabelArr(tkFxLbArr, fxLookback)

for [i, ln] in tkFxLnArr
    line.set_x2(ln, bar_index + LINE_OFFSET)
    if highlightCurFx and i != tkFxLnArr.size() - 1
        line.set_width(ln, tkFxWid)
    if showFxLb and barstate.islast
        label.set_x(tkFxLbArr.get(i), labelOffset)

// London
var ldnFxArr = array.new_line()
var ldnFxLbArr = array.new_label()

inLdnFx = IsTimeInRange(LONDON_FIX, ukDST ? GMT_DST : GMT)
isLdnFxBar = inLdnFx and not inLdnFx[1]

if showLdnFx and isLdnFxBar
    wid = highlightCurFx ? ldnFxWid + 1 : ldnFxWid
    ldnFxArr.push(line.new(bar_index, open, bar_index + LINE_OFFSET, open, color = ldnFxCor, style = LineStyle(ldnFxStyle), width = wid))
    TrimLineArr(ldnFxArr, fxLookback)
    if showFxLb
        ldnFxLbArr.push(label.new(x=labelOffset, y=open, text='London Fix', xloc=xloc.bar_time, color = NONE_COLOR, style=label.style_label_left, textcolor=ldnFxCor, textalign=text.align_left))
        TrimLabelArr(ldnFxLbArr, fxLookback)

for [i, ln] in ldnFxArr
    line.set_x2(ln, bar_index + LINE_OFFSET)
    if highlightCurFx and i != ldnFxArr.size() - 1
        line.set_width(ln, ldnFxWid)
    if showFxLb and barstate.islast
        label.set_x(ldnFxLbArr.get(i), labelOffset)