class COutGridEx {
private:
   int m_width;
   int m_height;
   Corner m_corner;
   int c_widths[];
   int c_heights[];
   int orig_loc_x;
   int orig_loc_y;
   int loc_x;
   int loc_y;
   int padding_hor;
   int padding_vert;
   string __id;

color NegateColor(color in){
    return (color) ((((int)in) & 0x00ffffff) ^0x00ffffff);
}

void OG_AddCell(int x,int y,int width,int height,Corner corner=CTopLeft,int fontsize=12,string fontname="Tahoma",color clr=clrWhite){
   string lname=StringFormat("__rect_%s_%d_%d",__id,x,y);
   string lname_t=StringFormat("__lbl_%s_%d_%d",__id,x,y);

   if(ObjectFind(0,lname)!=-1){ ObjectDelete(0,lname); }
   if(ObjectFind(0,lname_t)!=-1){ ObjectDelete(0,lname_t); }

   int __corner=0; int __anchor=0;

   c_widths[x]=width;
   c_heights[y]=height;
   ObjectCreate(0,lname,OBJ_RECTANGLE_LABEL,0,0,0);
   ObjectSetInteger(0,lname,OBJPROP_CORNER,__corner);
   ObjectSetInteger(0,lname,OBJPROP_ANCHOR,__anchor);
   ObjectSetInteger(0,lname,OBJPROP_BACK,1);
   ObjectSetInteger(0,lname,OBJPROP_BORDER_TYPE,4);
   ObjectSetInteger(0,lname,OBJPROP_BGCOLOR,clrNONE);
   ObjectSetInteger(0,lname,OBJPROP_SELECTABLE,0);
   ObjectSetInteger(0,lname,OBJPROP_HIDDEN,1);

   //
   ObjectCreate(0,lname_t,OBJ_LABEL,0,0,0);
   ObjectSetInteger(0,lname_t,OBJPROP_CORNER,__corner);
   ObjectSetInteger(0,lname_t,OBJPROP_ANCHOR,__anchor);
   ObjectSetInteger(0,lname_t,OBJPROP_COLOR,clr==clrNONE?(NegateColor(((color)ChartGetInteger(0,CHART_COLOR_BACKGROUND)))):clr);
   ObjectSetString(0,lname_t,OBJPROP_FONT,fontname);
   ObjectSetInteger(0,lname_t,OBJPROP_FONTSIZE,fontsize);
   ObjectSetString(0,lname_t,OBJPROP_TEXT," ");
   ObjectSetInteger(0,lname_t,OBJPROP_TIME3,ALIGN_LEFT);
   ObjectSetInteger(0,lname_t,OBJPROP_SELECTABLE,0);
   ObjectSetInteger(0,lname_t,OBJPROP_HIDDEN,1);
}

void OG_UpdateCell(int x,int y){
   string lname=StringFormat("__rect_%s_%d_%d",__id,x,y);
   string lname_t=StringFormat("__lbl_%s_%d_%d",__id,x,y);

   ObjectSetInteger(0,lname,OBJPROP_XDISTANCE,loc_x+x_offset_of(x,spacing_hor));
   ObjectSetInteger(0,lname,OBJPROP_YDISTANCE,loc_y+y_offset_of(y,spacing_vert));
   ObjectSetInteger(0,lname,OBJPROP_XSIZE,width_of(x));
   ObjectSetInteger(0,lname,OBJPROP_YSIZE,height_of(y));

   //ObjectSetInteger(0,lname_t,OBJPROP_XDISTANCE,loc_x+x_offset_of(x,spacing_hor));
   //ObjectSetInteger(0,lname_t,OBJPROP_YDISTANCE,loc_y+y_offset_of(y,spacing_vert));
   ObjectSetInteger(0,lname_t,OBJPROP_XDISTANCE,loc_x+x_offset_of(x,spacing_hor)+padding_hor);
   ObjectSetInteger(0,lname_t,OBJPROP_YDISTANCE,loc_y+y_offset_of(y,spacing_vert)+padding_vert);
   ObjectSetInteger(0,lname_t,OBJPROP_XSIZE,width_of(x));
   ObjectSetInteger(0,lname_t,OBJPROP_YSIZE,height_of(y));

   ENUM_ALIGN_MODE align=(ENUM_ALIGN_MODE)ObjectGetInteger(0,lname_t,OBJPROP_TIME3);
   P(x,y,ObjectGetString(0,lname_t,OBJPROP_TEXT),(int)ObjectGetInteger(0,lname_t,OBJPROP_COLOR),-1,align);
}

int x_offset_of(int x,int shift=0){
   int asize=ArraySize(c_widths);
   if(x<0 || x>=asize)return 0;
   
   int sum=0;
   for(int i=0;i<x;i++){ sum+=MathMax(0,c_widths[i]+shift); }
   return sum;
}

int y_offset_of(int y,int shift=0){
   int asize=ArraySize(c_heights);
   if(y<0 || y>=asize)return 0;
   
   int sum=0;
   for(int i=0;i<y;i++){ sum+=MathMax(0,c_heights[i]+shift); }
   return sum;
}

int width_of(int x){
   int asize=ArraySize(c_widths);
   if(x<0 || x>=asize)return 0;

   return c_widths[x];
}

int height_of(int y){
   int asize=ArraySize(c_heights);
   if(y<0 || y>=asize)return 0;
   return c_heights[y];
}

public:
   void SetLocation(int x,int y){
      orig_loc_x=x; orig_loc_y=y;
      UpdatePosition();
   }
   int GetLocationX(){ return loc_x; }
   int GetLocationY(){ return loc_y; }

   int spacing_hor;
   int spacing_vert;
   void SetSpacing(int hor,int vert){
      spacing_hor=hor;
      spacing_vert=vert;
   }
   void SetPadding(int hor,int vert){ padding_hor=hor;      padding_vert=vert; }
   
   COutGridEx(string _id,int width,int height,Corner corner,int default_width=100, int default_height=20){
      m_width=width;
      m_height=height;
      m_corner=corner;
      __id=_id;

      ArrayResize(c_widths,m_width);
      ArrayResize(c_heights,m_height);

      for(int y=0;y<m_height;y++){
         for(int x=0;x<m_width;x++){
            OG_AddCell(x,y,default_width,default_height,corner);
         }
      }
   }
   ~COutGridEx(){ Deinit(); }

   void Deinit(){
      ObjectsDeleteAll(0,StringFormat("__lbl_%s",__id));
      ObjectsDeleteAll(0,StringFormat("__rect_%s",__id));
   }

   void Update(){
      for(int y=0;y<m_height;y++){
         for(int x=0;x<m_width;x++){
            OG_UpdateCell(x,y);
         }
      }
   }
   
   int GetWidth(){ return m_width; }
   int GetHeight(){ return m_height; }

   void P(int x,int y,string msg,color clr=clrNONE,int fsize=-1,ENUM_ALIGN_MODE align=ALIGN_LEFT){
      string lname="";
      lname=StringFormat("__lbl_%s_%d_%d",__id,x,y);

      if(clr!=clrNONE) ObjectSetInteger(0,lname,OBJPROP_COLOR,clr);
      if(fsize!=-1){
         ObjectSetInteger(0,lname,OBJPROP_FONTSIZE,fsize);
      }

      ObjectSetString(0,lname,OBJPROP_TEXT,msg!=""?msg:" ");

      string _font=ObjectGetString(0,lname,OBJPROP_FONT);
      int _fontsize=(int)ObjectGetInteger(0,lname,OBJPROP_FONTSIZE);
      
      TextSetFont(_font,_fontsize*(-10));
      int __fwidth=0; int __fheight=0;
      TextGetSize(msg,__fwidth,__fheight);
      
      int __cwidth=width_of(x);
      //int __align_shift=loc_x+x_offset_of(x,spacing_hor);
      int __align_shift=loc_x+x_offset_of(x,spacing_hor)+padding_hor;
      if(align==ALIGN_RIGHT){
         //__align_shift+=__cwidth-__fwidth;
         __align_shift+=__cwidth-__fwidth-(padding_hor*2);
      } else if(align==ALIGN_CENTER){
         //__align_shift+=(__cwidth-__fwidth)/2;
         __align_shift+=(__cwidth-__fwidth)/2-(padding_hor);
      }

      ObjectSetInteger(0,lname,OBJPROP_XDISTANCE,__align_shift);
      ObjectSetInteger(0,lname,OBJPROP_TIME3,(int)align);

      int __cheight=height_of(y);
      //int __yalign_shift=loc_y+y_offset_of(y,spacing_vert);
      int __yalign_shift=loc_y+y_offset_of(y,spacing_vert)+padding_vert;
      __yalign_shift+=(__cheight-__fheight)/2; // middle
      //__yalign_shift+=__cheight-__fheight; // bottom
      ObjectSetInteger(0,lname,OBJPROP_YDISTANCE,__yalign_shift-1);

   }
   
   int GetCellTextWidth(int x,int y){
      string lname=StringFormat("__lbl_%s_%d_%d",__id,x,y);
      
      string _font=ObjectGetString(0,lname,OBJPROP_FONT);
      int _fontsize=(int)ObjectGetInteger(0,lname,OBJPROP_FONTSIZE);

      string msg=ObjectGetString(0,lname,OBJPROP_TEXT);

      TextSetFont(_font,_fontsize*(-10));
      int __fwidth=0; int __fheight=0;
      TextGetSize(msg,__fwidth,__fheight);
   
      return __fwidth;
   }
   int GetCellTextHeight(int x,int y){
      string lname=StringFormat("__lbl_%s_%d_%d",__id,x,y);
      
      string _font=ObjectGetString(0,lname,OBJPROP_FONT);
      int _fontsize=(int)ObjectGetInteger(0,lname,OBJPROP_FONTSIZE);

      string msg=ObjectGetString(0,lname,OBJPROP_TEXT);

      TextSetFont(_font,_fontsize*(-10));
      int __fwidth=0; int __fheight=0;
      TextGetSize(msg,__fwidth,__fheight);
   
      return __fheight;
   }

   void SetCellBgColor(int x,int y,color clr){
      string lname=StringFormat("__rect_%s_%d_%d",__id,x,y);
      ObjectSetInteger(0,lname,OBJPROP_BGCOLOR,clr);
   }

   void SetColumnWidth(int x,int new_width,bool autoupdate=false){
      int asize=ArraySize(c_widths);
      if(x<0 || x>=asize)return;

      c_widths[x]=new_width;
      if(autoupdate)Update();
   }
   int GetColumnWidth(int x){
      int asize=ArraySize(c_widths);
      if(x<0 || x>=asize)return 0;

      return c_widths[x];
   }

   void SetRowHeight(int y,int new_height,bool autoupdate=false){
      int asize=ArraySize(c_heights);
      if(y<0 || y>=asize)return;

      c_heights[y]=new_height;
      if(autoupdate)Update();
   }
   int GetRowHeight(int y){
      int asize=ArraySize(c_heights);
      if(y<0 || y>=asize)return 0;

      return c_heights[y];
   }

   void SetColumnAutoWidth(int x,int add=0){
      int maxwidth=0;

      for(int i=0;i<GetHeight();i++){ maxwidth=MathMax(maxwidth,GetCellTextWidth(x,i)); }
      SetColumnWidth(x,maxwidth+add);
      
      Update();
   }
   void SetRowAutoHeight(int y,int add=0){
      int maxheight=0;

      for(int i=0;i<GetWidth();i++){ maxheight=MathMax(maxheight,GetCellTextHeight(i,y)); }
      SetRowHeight(y,maxheight+add);

      Update();
   }

   void SetCellBorder(int x,int y, int type,int width,color clr,int style){
      string lname=StringFormat("__rect_%s_%d_%d",__id,x,y);
      ObjectSetInteger(0,lname,OBJPROP_BORDER_TYPE,type);
      ObjectSetInteger(0,lname,OBJPROP_WIDTH,width);
      ObjectSetInteger(0,lname,OBJPROP_COLOR,clr);
      ObjectSetInteger(0,lname,OBJPROP_STYLE,style);
   }

   void SetCellFont(int x,int y, string _font,int font_size){
      string lname=StringFormat("__lbl_%s_%d_%d",__id,x,y);
      ObjectSetString(0,lname,OBJPROP_FONT,_font);
      ObjectSetInteger(0,lname,OBJPROP_FONTSIZE,font_size);
   }

   int TableWidth(){
      int table_width=0; for(int i=0;i<GetWidth();i++){ table_width+=MathMax(0,c_widths[i]+spacing_hor); table_width-=spacing_hor; } return table_width;
   }
   int TableHeight(){
      int table_height=0; for(int i=0;i<GetHeight();i++){ table_height+=MathMax(0,c_heights[i]+spacing_vert); } table_height-=spacing_vert; return table_height;
   }

   string GetCellText(int x,int y){ string lname=StringFormat("__lbl_%s_%d_%d",__id,x,y); return ObjectGetString(0,lname,OBJPROP_TEXT); }

   void UpdatePosition(){
      int chart_width=(int)ChartGetInteger(0,CHART_WIDTH_IN_PIXELS);
      int chart_height=(int)ChartGetInteger(0,CHART_HEIGHT_IN_PIXELS);
      int table_width=TableWidth();
      int table_height=TableHeight();

      switch(m_corner){
         case CTopLeft:{ loc_x=orig_loc_x;loc_y=orig_loc_y; break; }
         case CBottomLeft:{ loc_x=orig_loc_x;loc_y=chart_height-orig_loc_y-table_height; break; }
         case CTopRight:{ loc_x=chart_width-orig_loc_y-table_width;loc_y=orig_loc_y; break; }
         case CBottomRight:{ loc_x=chart_width-orig_loc_y-table_width; loc_y=chart_height-orig_loc_y-table_height; break; }
      };
   }

};

int GetHash(string str){
   int sum=0;
   for(int i=0;i<StringLen(str);i++)sum=sum+(i+1)*StringGetChar(str,i);
   return(sum);
}

int PeriodAtIdx(string symbol,int timeframe,int shift){
   int s=MathMax(PeriodSeconds(PERIOD_H4),PeriodSeconds(timeframe));
   int sh=PeriodSeconds(PERIOD_D1);

   datetime dt_result=0;
   int idx=0;
   int i=0;
   while(true){
      datetime dt_0=iTime(symbol,timeframe,i);
      datetime dt_1=iTime(symbol,timeframe,i+1);
      
      if(dt_0==dt_1){ return -1;}

      int dd0=0;
      int dd1=0;
      
      if(PeriodSeconds(timeframe)<PeriodSeconds(PERIOD_H4)){
         dd0=(int)(dt_0/sh);
         dd1=(int)(dt_1/sh);
      } else {
         if(PeriodSeconds(timeframe)==PeriodSeconds(PERIOD_H4)){
            dd0=TimeDayOfYear(dt_0)/7;
            dd1=TimeDayOfYear(dt_1)/7;
         } else if(PeriodSeconds(timeframe)==PeriodSeconds(PERIOD_D1)){
            dd0=TimeYear(dt_0)*12+TimeMonth(dt_0);
            dd1=TimeYear(dt_1)*12+TimeMonth(dt_1);
         } else if(PeriodSeconds(timeframe)>=PeriodSeconds(PERIOD_W1)){
            dd0=TimeYear(dt_0)*12;
            dd1=TimeYear(dt_1)*12;
         }
      }

      if(PeriodSeconds(timeframe)<PeriodSeconds(PERIOD_D1)){
         if((dd0!=dd1 || dt_0-dt_1>=MathMax(PeriodSeconds(PERIOD_D1),PeriodSeconds(timeframe)))){ if(idx==shift)return i; else idx++; }
      } else {
         if(dd0!=dd1){ if(idx==shift)return i; else idx++; }
      }
      i++;
   }

   return -1;
}