{ Search Tag: WA-RSI }

inputs:
	Price( Close ) [
		DisplayName = "Price", 
		ToolTip = "Enter an EasyLanguage expression to use in the RSI calculations."],
	
	Length( 14 ) [
		DisplayName = "Length", 
		ToolTip = "Enter the number of bars used in the RSI calculation."],
	
	OverSold( 30 ) [
		DisplayName = "OverSold", 
		ToolTip = "Enter the level of the indicator at which you consider the market to be oversold (too low)."],
	
	OverBought( 70 ) [
		DisplayName = "OverBought", 
		ToolTip = "Enter the level of the indicator at which you consider the market to be overbought (too high)."],
	
	OverSColor( MyColors( "DodgerBlue" ) ) [
		DisplayName = "OverSColor", 
		ToolTip = "Oversold Color.  Enter the color to use when the indicator's value is below OverSold."], 
	
	OverBColor( Red ) [
		DisplayName = "OverBColor", 
		ToolTip = "Overbought Color.  Enter the color to use when the indicator's value is above OverBought."];

variables:  
	RSIValue( 0 );

RSIValue = RSI( Price, Length );
 
Plot1( RSIValue, !( "RSI" ) );
Plot2( OverBought, !( "OverBot" ) );
Plot3( OverSold, !( "OverSld" ) );

{ color criteria }
if RSIValue > OverBought then 
	SetPlotColor( 1, OverBColor ) 
else if RSIValue < OverSold then 
	SetPlotColor( 1, OverSColor );

{ alert criteria }
if AlertEnabled then
begin
	if RSIValue crosses over OverSold then
		Alert( !( "Indicator exiting oversold zone" ) )
	else if RSIValue crosses under OverBought then
		Alert( !( "Indicator exiting overbought zone" ) );
end;
	

{ ** Copyright © TradeStation Technologies, Inc.  All Rights Reserved ** 
  ** TradeStation reserves the right to modify or overwrite this analysis technique 
     with each release. ** }